Variables

Les variables sont des espaces réservés qui stockent des valeurs pouvant changer. Utilisez-les lorsqu’une valeur est différente chaque fois qu’un script s’exécute. Par exemple, ANI est une variable qui contient l’ANI Aussi connu sous le nom d’id de l’appelant. numéro de téléphone listé d’un appel entrant, ou d’un appel vocal entrant. de l’appelant, ou son numéro de téléphone. Lorsque ANI est utilisé dans un script, il contient l’id de l’appelant du contact. Chaque fois que le script s’exécute, il traite un contact différent, de sorte que la valeur de ANI change.

Vous pouvez créer vos propres variables chaque fois que vous en avez besoin. Les variables peuvent contenir des valeurs uniques. Elles peuvent également contenir des objets de données dynamiques et des tableaux.

Certaines variables utilisées dans les scripts Studio sont définies par le système. Cela signifie qu’elles font partie du code à l’intérieur des actions Exécute un processus dans un script Studio, comme la collecte de données clients ou la lecture de musique. Studio, vous n’avez donc pas besoin de les créer. Il existe deux types de variables définies par le système :

• Variables réservées : variables En lecture seule que vous pouvez utiliser lorsque vous devez inclure un type spécifique d’informations dans votre script.
• Variables prédéfinies : variables déjà définies. Elles sont inscriptibles, vous pouvez donc leur attribuer une valeur.

Essayez-le

Téléchargez le script d’exemples de variables et importez-le dans Studio. Les exemples de cette page d’aide sont disponibles dans les actions Snippet du script d’exemple. Vous pouvez ouvrir la fenêtre de l’éditeur Snippet et exécuter le débogueur pour voir comment fonctionne chaque exemple.

Résumé de la syntaxe des variables

La liste suivante résume la syntaxe des variables. Plus d’informations sur ces points sont disponibles dans d’autres sections de cette page.

• Créez une variable et attribuez-lui une valeur à l’aide d’une ASSIGN action ou d’une Snippet action. Dans une Snippet, vous pouvez utiliser le ASSIGN mot-clé lorsque vous déclarez une variable. Cela est facultatif, mais fortement recommandé. Utilisez cette syntaxe dans une Snippet : ASSIGN <var name> = <var value> ou <var name> = <var value>.

• When assigning values to a variable: 
  • Les chaînes et les valeurs de date et d’heure doivent être placées entre guillemets simples ou doubles. Par exemple : ASSIGN life = "forty-two".
  • Pour attribuer une valeur de date et d’heure qui sera utilisée avec des fonctions de date et d’heure, placez un signe dièse ( # ) devant la valeur, mais à l’extérieur des guillemets doubles. Par exemple : ASSIGN var = #"02/09/2023". Si la valeur de date et d’heure ne sera pas utilisée avec des fonctions de date et d’heure, il n’est pas nécessaire d’utiliser le signe dièse. Cependant, sans le signe dièse, la valeur est de type chaîne et non de type date/heure.
  • Les valeurs numériques ne doivent pas être placées entre guillemets. Si vous placez une valeur numérique entre guillemets, elle est traitée comme une chaîne sauf si elle est évaluée dans une expression mathématique.
  • Les expressions numériques et booléennes Un type de données qui a deux valeurs possibles : true et false. ne peuvent pas être placées entre guillemets. Si une de ces expressions est entre guillemets, elle est traitée comme une chaîne. Par exemple : ASSIGN myVar = var2 > 42 est évalué à vrai ou faux selon la valeur de var2. Cependant, ASSIGN myVar = "var2 > 42" entraîne que la valeur de myVar soit littéralement var2 > 42.
  • Les valeurs booléennes ne doivent pas être mises entre guillemets.
  • Utilisez des séquences d'échappement si vous devez inclure les caractères suivants dans une valeur de chaîne : guillemets doubles ( " ), guillemet simple ( ' ), accolade ouvrante ( ), tabulation (ASCII 9), retour chariot (ASCII 13), saut de ligne (ASCII 10), retour arrière (ASCII 8), null.
• When substituting a variable's value in a string: 
  • Placez les variables entre accolades. Par exemple : ASSIGN myVar = "the meaning of life is {life}"
  • Si la variable est un objet de données dynamiques, vous devez faire référence à une propriété au sein de l'objet. Par exemple : ASSIGN myVar = "the meaning of life is {anObj.thisProperty}". Le fait de faire référence uniquement à l'objet entraînera une erreur.
  • Si la variable contient un tableau, vous devez inclure l'index de la valeur que vous souhaitez affecter. Par exemple : ASSIGN myVar = myArray[4].
• When assigning the value of one variable to another:
  • Vous n’avez pas besoin de guillemets doubles ou d’accolades. Par exemple : ASSIGN myVar = var2. Cela entraîne l'affectation d'une copie de la valeur de la variable à myVar.
  • Si une variable contient un tableau, vous pouvez l’affecter à une autre variable.
  • Si une variable est un objet, vous ne pouvez l’affecter qu’à un autre objet.

• Lorsque vous faites référence à des variables dans les propriétés d'Action Studio, les directives suivantes s'appliquent généralement. Reportez-vous toujours à la page d'aide en ligne de l'Action que vous utilisez, car il existe des exceptions à ces énoncés.

  • Les propriétés attendent soit une variable, soit des données. Les données peuvent consister en des éléments littéraux ou des variables. Lorsqu'une propriété attend des données, elle peut généralement accepter soit un élément littéral, soit une variable. Toutefois, des exceptions existent; reportez-vous donc toujours à l'aide en ligne de l'action si vous n'êtes pas certain de ce qu'attend une propriété.

  • Si la propriété attend un nom de variable, saisissez le nom de la variable sans accolades.

  • Si la propriété attend des données et que vous souhaitez utiliser la substitution de variable, placez le nom de variable entre accolades : {varName}.

Types de données et typage implicite

Les types de données définissent le type de données qu’une variable contient et la manière dont elles doivent être utilisées dans le programme. Dans Studio, les variables peuvent avoir les types de données suivants :

• Chaîne : la valeur de la Variable contient des caractères alphanumériques et spéciaux, comme des points, des virgules et des traits de soulignement. Les valeurs de type chaîne doivent être placées entre guillemets.
• Numérique : la valeur de la Variable est un nombre. Les valeurs Numériques n’ont pas besoin de guillemets.
• Date/heure : la valeur de la Variable est une date, une heure, ou les deux. Lorsqu’une valeur de date/heure est utilisée avec des fonctions de date/heure dans Studio, la valeur doit être placée entre guillemets et précédée d’un signe dièse à l’extérieur des guillemets : var = #"11-23-2022".
• Booléen : la valeur de la Variable est soit true ou 1, soit false ou 0. Ne placez pas les valeurs booléennes entre guillemets.

Dans de nombreux langages de programmation et de script, vous devez affecter explicitement un type de données à une variable lorsque vous la créez. Dans Studio, les variables sont typées implicitement. Le compilateur Studio détermine le type de chaque variable lorsqu'il compile le script. Cela signifie que vous n'avez pas besoin de définir le type de données pour les variables que vous utilisez. La seule exception est lorsqu'une variable contient une valeur de date/heure que vous souhaitez utiliser avec des fonctions de date/heure.

Inférence de type

Le typage implicite influe sur la manière dont les variables sont évaluées. Par exemple, les comparaisons de variables donnent des résultats différents selon le type que Studio reconnaît pour les variables. Le comportement par défaut dans Studio est que tout est traité comme une chaîne jusqu'à ce que des calculs mathématiques soient requis. Ensuite, si quelque chose peut être évalué comme un nombre, il le sera, même s'il est placé entre guillemets. C’est ce qu’on appelle l’inférence de type.

Le compilateur Studio reconnaît une valeur comme numérique même si elle est placée entre guillemets. Les guillemets indiquent qu’une valeur est une chaîne. Lorsqu'une valeur numérique est placée entre guillemets, Studio la traite comme une chaîne, sauf si vous l'utilisez dans des calculs mathématiques dans le script. Par exemple :

var1 = "42"

var2 = 42



var3 = var2 + var1	

Le résultat de l'exemple est var3 = 84. Studio déduit que la valeur de var1 est numérique et la traite comme telle lors de l'évaluation de l'expression dans var3, même si elle est placée entre guillemets doubles.

Créer des variables

Vous pouvez créer vos propres variables à utiliser dans des scripts. Vous pouvez le faire à l'aide d'une Action Assign ou d'une Action Snippet dans le script.

Assigner une action

L'Assign action vous permet de créer une seule variable et de lui attribuer une valeur. Vous procédez ainsi à l'aide des propriétés Variable et Valeur de l'action. L'avantage de Assign est qu'il s'agit d'une façon facile à utiliser et configurable de créer des variables.

Cette action possède d'autres propriétés qui vous permettent de définir comment la variable est utilisée. Vous pouvez :

• Faire en sorte que la valeur de la variable soit incluse dans le screen pop qui est attribué au niveau de la ACD Compétence Utilisé pour automatiser la livraison des interactions en fonction des compétences, des aptitudes et des connaissances de l’agent..
• Enregistrer la valeur de la variable dans la base de données.

Action d'Extrait de code

L'Snippet action est une façon basée sur le code de créer des variables. À l'aide d'une seule action, vous pouvez créer une ou plusieurs variables, en plus de tout autre code personnalisé que vous pourriez avoir besoin d'inclure. L'avantage d'utiliser Snippet est que si vous souhaitez ajouter d'autres variables à votre script plus tard, vous pouvez les ajouter à la même action. Vous n'avez pas besoin d'ajouter d'autres actions et de refaire les connecteurs de votre script, comme vous auriez dû le faire si vous aviez initialement utilisé une action Assign.

Utilisez l’un des formats de syntaxe suivants :

ASSIGN varName = value ou varName = value

Vous pouvez ajouter à la variable des propriétés qui correspondent aux propriétés de l'action Assign :

• Pour que la valeur de la variable soit incluse dans un screen pop, ajoutez setscreenpop(1) au nom de variable.
• Pour que la valeur de la variable soit sauvegardée dans la base de données, ajoutez savetodb(1) au nom de variable.

Par exemple :

ASSIGN epicPoem = "Beowulf"

epicPoem.setscreenpop(1)

epicPoem.savetodb(1)

Pour les deux propriétés, le 1 est une valeur booléenne Un type de données qui a deux valeurs possibles : true et false. qui définit la propriété sur true.

Faits importants à connaître au sujet de la création de variables dans les actions Snippet :

• Il n’est pas nécessaire de déclarer le type lorsque vous déclarez une variable, sauf pour les variables date/heure.
• L'inclusion du mot-clé ASSIGN est facultative. Toutefois, il est recommandé d'utiliser ce mot-clé chaque fois que vous créez une variable.
• Si vous déclarez une variable dans un sous-script et que vous souhaitez qu'elle soit renvoyée au script d'origine, ajoutez global: au début du nom de variable. Cela indique que sa portée est globale.

Guillemets simples, guillemets doubles ou aucun guillemet

Lors de l'affectation de la valeur d'une variable à une autre variable, certaines valeurs doivent être placées entre guillemets. D'autres valeurs n'ont pas besoin de guillemets. Suivez les directives suivantes :

• Les valeurs de chaîne doivent être placées entre guillemets simples ou doubles. Cela est vrai même si le nom de variable se termine par un signe dollar. Si une chaîne n'est pas entre guillemets, le script considère que la valeur est une variable. Dans l'exemple suivant, a1, a2 et a1$ sont tous évalués à la valeur littérale Example. La valeur de a3 et a3$ dépend du fait que Example a été déclaré ou non comme variable. Si une variable Example existe dans le script, a3 et a3$ sont évalués à la valeur de Example. Si Example n'existe pas, a3 et a3$ donnent des valeurs vides.

  ASSIGN a1 = "Example"
  
  ASSIGN a2 = 'Example'
  
  ASSIGN a1$ = "Example"
  
  ASSIGN a3 = Example
  
  ASSIGN a3$ = Example

• Les valeurs numériques ne nécessitent pas de guillemets. Toutefois, vous pouvez les utiliser si vous le souhaitez. Dans l'exemple suivant, b1, b2 et b3 sont tous évalués à 123.

  ASSIGN b1 = "123" 
  
  ASSIGN b2 = '123' 
  
  ASSIGN b3 = 123

• Expressions Numériques ne peuvent pas être placées entre guillemets. Cela comprend les expressions mathématiques et booléennes Un type de données qui a deux valeurs possibles : true et false.. Si vous placez une expression Numérique entre guillemets, elle est traitée comme du texte. Par exemple, c1 = 123 + 456 donne 579, mais c2 = "123 + 456" donne 123 + 456.
• Les valeurs date/heure doivent être placées entre guillemets si vous les déclarez comme étant du type date/heure.
• Les valeurs booléennes ne doivent pas être mises entre guillemets.
• Si vous affectez la valeur d’un tableau ou d’un membre d’objet dynamique à une variable, n’utilisez pas de guillemets ou d’accolades avec le nom du tableau ou du membre d’objet.

Créer des variables avec des valeurs date/heure

Studio n'identifie pas implicitement la date/l'heure comme un type. Toutefois, vous pouvez ajouter un identifiant avant une valeur de variable pour la déclarer comme étant de ce type. Vous devez le faire uniquement si la valeur doit être utilisée dans des fonctions de date/heure ou si vous souhaitez effectuer des opérations avec la valeur.

Pour déclarer une valeur de variable comme étant une date/heure, utilisez la syntaxe ASSIGN <varName> = #"<datetime>", où <datetime> est la valeur date/heure que vous souhaitez stocker dans la variable. Par exemple, date1 = #"7/15/2050 5:00pm". Si une variable n'est pas déclarée comme étant une date/heure, vous pouvez utiliser la asdatetime() fonction pour la convertir en une telle valeur.

Certaines fonctions qui manipulent les dates et les heures exigent que les variables soient déclarées comme étant de type date/heure. Même si le format de la date et de l’heure est correct, la fonction ne fonctionnera pas si la variable n’est pas correctement déclarée. Vous pouvez également utiliser cette syntaxe pour effectuer des opérations sur les dates et les heures que vous ne pourriez pas faire autrement. Par exemple, vous pouvez les comparer :

date1 = #"7/15/2050 5:00pm" 
date2 = #"7/15/2050 4pm"
x = date1 > date2 

Le résultat est 1 (vrai), car la valeur littérale de date1 est supérieure à la valeur littérale de date2.

Dénomination des variables

Nommez les variables en suivant ces directives :

• Utilisez des caractères alphanumériques (a-z, A-Z, 0-9).

• Le premier caractère du nom doit être une lettre.
• Utilisez le caractère de soulignement ( _ ) et le signe du dollar ( $ ) n'importe où dans le name.
• Si le dernier caractère d'un nom de variable est un signe de dollar, la valeur est traitée comme du texte.
• N’utilisez pas les noms de variables prédéfinies ou de mots réservés.

Substitution de variables

Lorsque vous devez utiliser la valeur d’une variable dans votre script, incluez le nom de la variable dans le code de l’extrait ou dans le champ de propriété de l’action.

Si vous substituez la valeur de la variable dans une chaîne, placez le nom de la variable entre accolades. Dans une chaîne, tout est traité comme du texte brut, sauf si c'est formaté comme une variable. Par exemple :

ASSIGN foeName = "Grendel"

ASSIGN numberFoes = "3"

ASSIGN x = numberFoes

ASSIGN y = "One of Beowulf's foes is {foeName}. He faced {numberFoes} foes in all." 

ASSIGN z = "One of Beowulf's foes is foeName. He faced numberFoes in all." 

Les résultats de cet exemple sont et .

• x=3.
• y=One of Beowulf's foes is Grendel. He faced 3 foes in all.
• z=One of Beowulf's foes is foeName. He faced numberFoes in all.

Lorsque vous copiez la valeur d’une variable dans une autre variable, vous n’avez pas besoin d’utiliser les accolades. Cela s’applique aux valeurs textuelles et numériques. Dans l’exemple suivant, le résultat est : x=3 et z=Grendel :

ASSIGN numberFoes = "3"

ASSIGN name = "Grendel"

ASSIGN x = numberFoes 

ASSIGN y = name 

Si vous effectuez des opérations mathématiques avec des variables, il n’est pas nécessaire de les placer entre accolades. Dans l’exemple suivant, le résultat est y=200.

ASSIGN a1 = "100"

ASSIGN a2 = "100.00"

ASSIGN y = (a1 + a2) 

Substitution de variables dans les propriétés d’action

De nombreuses propriétés d’action peuvent accepter des variables à la place de valeurs littérales. Cela est vrai même si la page d’aide de l’action ne précise pas que vous pouvez utiliser une variable pour configurer une propriété.

L’utilisation de variables dans les propriétés d’action permet de réutiliser les scripts. Par exemple, si votre organisation compte trois secteurs d’activité, vous auriez besoin de trois scripts de mise en file d’attente pour définir la ACD compétence Utilisé pour automatiser la livraison des interactions en fonction des compétences, des aptitudes et des connaissances de l’agent., la gestion des priorités et d’autres paramètres pour chaque secteur d’activité si vous utilisez des valeurs littérales. Si vous utilisez des variables pour configurer les propriétés dont la valeur diffère selon les secteurs d’activité, vous pouvez avoir un seul script au lieu de trois.

Lorsqu’il est fait référence à des variables dans les propriétés d’action Studio, les lignes directrices suivantes s’appliquent généralement :

• Les propriétés attendent soit une variable, soit des données. Les données peuvent consister en des éléments littéraux ou des variables. Lorsqu'une propriété attend des données, elle peut généralement accepter soit un élément littéral, soit une variable. Toutefois, des exceptions existent; reportez-vous donc toujours à l'aide en ligne de l'action si vous n'êtes pas certain de ce qu'attend une propriété.

• Si la propriété attend un nom de variable, saisissez le nom de la variable sans accolades.

• Si la propriété attend des données et que vous souhaitez utiliser la substitution de variable, placez le nom de variable entre accolades : {varName}.

Passer des valeurs de variables d'un script à l'autre

Les valeurs variables peuvent passer d'un script à l'autre. Elles peuvent provenir de ce qui suit :

• Script d'origine vers Subscript : toutes les variables du script d'origine sont présentes et disponibles pour être utilisées dans les subscripts. Cependant, elles sont dans la portée globale. Pour les utiliser dans les subscripts, vous devez faire précéder le nom de la variable de global:. Par exemple, global:varName. Cela comprend les variables système prédéfinies et les variables que vous créez.
• Subscript vers script d'origine : les variables que vous déclarez dans un subscript ne sont pas automatiquement retransmises au script d'origine. Si vous souhaitez retransmettre une variable personnalisée d'un subscript au script d'origine, vous devez la déclarer comme globale. De même, si vous déclarez des variables dans un sous-subscript, vous devez les déclarer comme globales et les référencer comme globales dans le subscript et dans le script d'origine de haut niveau.

Vous pouvez afficher les variables globales dans les traces de script. Vous devrez peut-être activer cette option dans la fenêtre de Sortie de trace lors de l'affichage d'une trace.

Certaines données peuvent provenir d'une source extérieure à vos scripts, comme un CRM systèmes tiers qui gèrent des éléments tels que les contacts, les informations de vente, les détails de soutien et les historiques de cas. ou un appel API Interface de programmation d’applications. Vous permet d’automatiser certaines fonctionnalités en connectant votre système NiCE CXone à d’autres logiciels.. Vous pouvez transmettre ces valeurs à des subscripts ou à des scripts générés à l'aide de la propriété Paramètres dans l'action RunSub ou l'action Spawn. L'action Begin possède également une propriété Paramètres. Configurez l'action Begin dans le subscript avec les noms des variables destinées à recevoir les valeurs transmises par RunSub ou Spawn.

Si les données que vous devez transmettre sont contenues dans un objet, l'objet doit d'abord être converti en JSON ou en XML. Vous pouvez transmettre la variable qui contient la chaîne JSON ou XML. Dans le deuxième script, vous pouvez reformer les données en un objet, si vous le souhaitez.

Comparaison et Évaluation des variables

Le fait que Studio attribue implicitement un type aux variables a une incidence sur la façon dont elles sont évaluées dans les expressions et les comparaisons booléennes Un type de données qui a deux valeurs possibles : true et false..

Par exemple :

ASSIGN a1 = "100"

ASSIGN a2 = "100"

ASSIGN y = (a1 = a2)

Dans cet exemple, l’expression y = (a1 = a2) est évaluée à y = 1 (vrai).

Forcer la comparaison sous forme de texte

Vous pouvez forcer une variable à être évaluée en tant que texte même si sa valeur est numérique. Vous pouvez le faire de deux façons :

• Ajoutez un signe dollar à la fin du nom de la variable. Par exemple : varName$ = 42. Lors d'une comparaison, une seule des deux variables a besoin d'un suffixe de signe dollar.
• Entourez les noms des variables d’accolades et de guillemets doubles. Par exemple, y = ("{a1}" = "{a2}").

Lorsqu'un nom de variable se termine par un signe dollar, toutes les opérations booléennes Un attribut d'informations qui définit la façon dont elles sont utilisées dans un programme, comme un entier (nombres pouvant être manipulés) ou un booléen (vrai/faux). (=, >, <, >=, <=) utilisant cette variable traitent la valeur comme du texte. Par exemple :

ASSIGN a$ = 20
ASSIGN b = 100
ASSIGN x = a$ > b

Dans cet exemple, la variable x est 1 (vrai). Étant donné que la variable a$ se termine par un signe de dollar, la valeur 20 est traitée comme du texte. Cela signifie que a$ > b est une comparaison de 20 et 100 en tant que chaînes de texte et non en tant qu'entiers. Lorsque la comparaison est effectuée en tant que texte, 20 est plus grand que 100, car 20 commence par un 2 et 100 commence par un 1. Sans le signe de dollar dans le nom de variable, x = a > b est 0 (faux), car les valeurs sont comparées en tant qu'entiers. L'entier 20 n'est pas plus grand que l'entier 100.

Variables réservées et prédéfinies

Il existe des variables préexistantes dans Studio. Elles sont les suivantes :

• Variables réservées : Ces variables renvoient un certain type d’informations, comme l’heure actuelle ou l’ID du fuseau horaire actuel. Les variables réservées sont en lecture seule, ce qui signifie qu’un script ne peut pas y enregistrer de valeurs. Elles existent uniquement pour renvoyer des informations. Vous pouvez les utiliser dans votre script lorsque vous souhaitez saisir les informations qu’elles renvoient.
• Variables prédéfinies : ce sont des variables système. Elles sont déjà définies dans Studio, vous pouvez donc les utiliser dans vos scripts sans avoir à les créer. Utilisez les variables système dans vos scripts chaque fois que vous avez besoin des informations qu’elles contiennent. Ne remplacez les variables système prédéfinies que si l’aide en ligne ou un représentant de compte vous demande de le faire. Vous pouvez en savoir plus sur les variables prédéfinies.

Variables globales

Les variables globales vous permettent de déclarer une variable dans un sous-script et de la faire automatiquement renvoyer au script d’origine après l’action Return. Lorsque vous déclarez une variable globale dans un sous-script, vous n’avez pas besoin de la renvoyer au script d’origine avec l’action Return.

Vous pouvez créer une variable globale à l’aide de l’action Snippet ou de l’action Assign. Utilisez la syntaxe suivante lorsque vous créez une variable globale avec Snippet :

ASSIGN global:<variable name>

ASSIGN global:<variable name>="{firstname} {lastname}"

Assurez-vous qu’il n’y a pas d’espace entre les deux-points et le nom de variable.

Si vous utilisez l’action Assign, n’incluez pas le mot-clé ASSIGN.

Vous n’avez pas besoin de déclarer les variables du script d’origine comme globales. Le fait de limiter la déclaration des variables globales aux sous-scripts vous donne un indice visuel sur le script dans lequel vous travaillez. Lorsque vous voyez global:var, vous savez que vous êtes dans un sous-script.

Exemple de variables globales

L'exemple suivant montre comment utiliser des variables globales.

Rédaction de Variable

La rédaction de variable élimine les valeurs de variable des traces et des journaux générés par un script. Vous pouvez masquer des variables et des objets.

La rédaction est configurée au niveau du script dans le champ VariableRedaction des propriétés du script. Les valeurs Masquées sont remplacées par une chaîne de X caractères. La longueur de la valeur de la variable détermine le nombre de X utilisés, ce qui signifie qu'un mot masqué de cinq lettres entraînerait cinq X. La rédaction partielle de variable, comme une partie d'un numéro de carte de crédit, n'est pas prise en charge.

Pour masquer des variables :

1. Dans NiCE CXone, cliquez sur le sélecteur d'applications et sélectionnez Omnicanal Routing > Studio .
2. Sur la page Scripts, repérez et double-cliquez pour ouvrir le script que vous voulez utiliser. Le script s'ouvre dans un nouvel onglet.
3. Dans le panneau de propriétés situé à droite du script, cliquez sur l’onglet Variables.

4. Cliquez sur Masqué .

   Afficher l’image)

   

5. Dans le champ de l'onglet Variables, entrez le nom de chaque variable que vous souhaitez masquer. Appuyez sur entrée après chaque variable. Ces noms doivent correspondre aux variables créées dans les actions Assign ou SNIPPET du script.

6. Cliquez de nouveau sur Masqué pour masquer la liste des noms de variable.

7. Enregistrez votre script.

Supprimer des Données sensibles d'une variable

En plus de configurer la rédaction de variable, vous pouvez configurer votre script pour supprimer les données sensibles d'une variable. Cela permet de s'assurer qu'elles ne persistent pas dans le script plus longtemps que nécessaire.

1. Dans votre script, placez une action Snippet après que les données sensibles ont été utilisées et ne sont plus nécessaires.
2. In the Snippet editor of the Snippet action, add the appropriate line for each variable you want to clear sensitive data from: 
   • Pour un objet de données dynamiques : DYNAMIC <object name>
   • Pour une variable régulière : ASSIGN <var name> = ""
3. Enregistrez vos modifications.

Afficher toutes les variables d'un script

Il existe deux manières d'afficher toutes les variables de votre script :

• L'onglet Variables. Cet onglet fait partie du volet des propriétés situé à droite du canevas du script. Vous pouvez cliquer sur la flèche à côté d'une variable pour développer une liste de toutes les actions du script qui modifient cette variable.
• Vous pouvez aussi voir les variables utilisées dans un script lorsque vous exécutez une trace. Au fur et à mesure que vous sélectionnez chaque ligne dans la Sortie de la trace, les variables du script à ce point sont visibles dans le volet Variables. Vous pouvez cliquer sur chaque ligne de la trace pour voir comment le contenu des variables change au fil de la progression du script.