Benutzerdefinierte Code-Snippets

Einige Skripte erfordern eine komplexere Programmierung, die über den Funktionsumfang von Studio-Aktionen hinausgeht. Studio bietet Ihnen die Möglichkeit, Ihren Skripten benutzerdefinierten Code hinzuzufügen. So können Sie Ihre Skripte an die spezifischen Anforderungen Ihres Unternehmens anpassen.

Die Erstellung von benutzerdefiniertem Code setzt Skript- oder Programmierkenntnisse voraus. Studio verwendet eine eigene Programmiersprache namens Snippet. NICE CXone hat diese Sprache speziell zur Verwendung mit Studio entwickelt. Zum Erlernen dieser Sprache steht ein vollständiges technisches Referenzhandbuch in der Online-Hilfe zur Verfügung.

Wichtige Fakten über Snippets

• Mithilfe von Code-Snippets können Sie die Struktur und Effizienz Ihrer Skripte verbessern. Sie können damit die ausgeführten Prozesse besser steuern und genauer festlegen, wann und wie sie ausgeführt werden. Sie können eigene Variablen und Objekte erstellen und mithilfe von Anweisungen wie IF, FOR und FOREACH Programmierlogik hinzufügen.
• Einige Produkte und Funktionen erfordern Snippets, Sie können sie aber auch dann in Ihren Skripten verwenden, wenn sie nicht zwingend erforderlich sind.
• Wenn für ein Produkt oder eine Funktion Code-Snippets erforderlich sind, bietet die Online-Hilfe ausführliche Informationen über die Snippets, die Sie verwenden müssen. Außerdem stehen Skriptbeispiele zur Verfügung, die zeigen, wie die Code-Snippets in Skripten verwendet werden. Zum Implementieren der Produkte oder Funktionen ist möglicherweise eine weitere Skriptbearbeitung erforderlich.
• Die Snippet-Skriptsprache basiert auf dem .NET-Framework. Sie wird serverseitig ausgeführt und in MSIL (Microsoft Intermediate Language) kompiliert, wie C# und Visual Basic .NET.

Snippet-Aktion

Damit Sie Ihren Skripten benutzerdefinierten Code hinzufügen können, benötigen Sie eine Snippet-Aktion. Sie können auf diese Aktion doppelklicken, um ein Editor-Fenster zu öffnen, in dem Sie den benutzerdefinierten Code hinzufügen können. Im Editor-Fenster können Sie Ihren Code auch debuggen. Möglicherweise ist mehr als eine Snippet-Aktion in Ihrem Skript erforderlich. Wenn Sie mehrere Aktionen verwenden, geben Sie in das Feld Hinzufügen Caption für jede Aktion eine Beschreibung ein.

Die Platzierung einer Snippet-Aktion ist wichtig. Wenn ein Snippet einer Variablen einen Wert zuweist, muss sie vor der Aktion platziert werden, die den Wert benötigt. Wenn ein Snippet dagegen Code für eine Entscheidung enthält, die sich nach dem an sie übergebenen Wert richtet, muss das Snippet nach der Aktion platziert werden, die den Wert bereitstellt.

Snippets im Vergleich mit Aktionen

Einige Aufgaben, die Snippets durchführen können, lassen sich auch mithilfe von Studio-Aktionen implementieren. Beispielsweise gibt es Aktionen für die Anweisungen IF und FOR. Mit der Aktion ASSIGN können Sie eine benutzerdefinierte Variable erstellen und ihr einen Wert zuweisen. Diese Aktionen bieten eine akzeptable Methode, um Ihrem Skript die entsprechende Funktionalität hinzuzufügen. Snippets sind jedoch effizienter.

In Snippets platzierter Code hat mehrere Vorteile: Ihr Skript ist übersichtlicher und besser strukturiert und Sie können einfacher im Skript navigieren. Dadurch wird die Skripterstellung einfacher und effizienter. Wenn Sie es sich angewöhnen, Variablen immer in Snippets zu deklarieren, ist die Suche nach einer bestimmten Deklaration in Zukunft einfacher, da weniger Orte durchsucht werden müssen.

Hinzufügen von benutzerdefiniertem Code zu einem Skript

Mithilfe der Snippet--Aktion können Sie Ihren Skripten benutzerdefinierten Code hinzufügen. Sie finden diese Aktion auf der Registerkarte "Extras" im Bereich "Erweitert" der Standardpalette.

1. Öffnen Sie Ihr Skript in Studio.
2. Fügen Sie an der Stelle, an der der Code erforderlich ist, eine Snippet-Aktion in Ihr Skript ein und verbinden Sie sie mit den anderen Aktionen.
3. Doppelklicken Sie auf die Aktion, um das Editor-Fenster zu öffnen. Hier können Sie Ihren Code hinzufügen.

4. Klicken Sie auf die Registerkarte, auf der Sie den Code hinzufügen möchten. Jede Registerkarte bietet eine eigene Methode zum Hinzufügen von Code. Folgende Registerkarten sind verfügbar:

   • Strukturansicht: Hier können Sie benutzerdefinierten Code erstellen, indem Sie in einer Liste Befehle auswählen, die von der Anwendung angeboten werden. Sie können den Befehl auswählen und die erforderlichen Details angeben, um ihn zu konfigurieren.

     Bild der Registerkarte "Strukturansicht" im Snippet-Editor-Fenster anzeigen.

     

   • Textansicht: Hier können Sie manuell benutzerdefinierten Code eingeben. Diese Option setzt gute Kenntnisse bei der grundlegenden Skripterstellung voraus.

     Bild der Registerkarte "Textansicht" im Snippet-Editor-Fenster anzeigen.

     

5. Debuggen Sie Ihren Code, sofern gewünscht.

6. Sie können Ihre Änderungen jederzeit speichern, ohne das Editor-Fenster zu schließen, indem Sie auf Apply klicken.
7. Klicken Sie auf OK, wenn Sie die Bearbeitung des Codes abgeschlossen haben.

Code mit Textansicht

Auf der Registerkarte "Textansicht" im Snippet-Fenster können Sie Ihren Snippet-Code manuell erstellen. Zum Erlernen dieser Sprache steht ein vollständiger Referenzleitfaden in der Online-Hilfe zur Verfügung.

1. Öffnen Sie Ihr Skript in Studio.
2. Fügen Sie Ihrem Skript die Snippet-Aktion hinzu und doppelklicken Sie darauf, um das Snippet-Fenster zu öffnen.
3. Geben Sie auf der linken Seite der Registerkarte "Strukturansicht" Ihren Code ein. Sie können den Code eintippen oder aus einer anderen Quelle kopieren und einfügen, beispielsweise von dieser Hilfeseite oder aus einem anderen Skript.
4. Sie können jederzeit auf die Registerkarte Tree View klicken, um Code aus den vordefinierten Schlüsselwörtern hinzuzufügen. Mit den nach oben und unten gerichteten Pfeilen können Sie den Code für ein Schlüsselwort an eine andere Stelle im Skript verschieben.
5. Klicken Sie auf das Symbol Check Syntax , um zu überprüfen, ob die Syntax für den vorliegenden Code korrekt ist. Wenn keine Fehler vorliegen, wird im Status-Feld in der Symbolleiste unten auf der Registerkarte "Textansicht" der Status Okay angezeigt. Wenn Fehler vorhanden sind, wird eine Fehlermeldung eingeblendet und im Status-Feld in der Symbolleiste wird eine Meldung angezeigt. Die Meldung kann zum Beispiel folgendermaßen lauten: Error at line 4.
6. Klicken Sie auf das Symbol Comment , um die Zeile, in der sich der Cursor gerade befindet, in einen Kommentar umzuwandeln.
7. Klicken Sie auf das Symbol Uncomment , um die Kommentarzeichen aus der Zeile zu entfernen, in der sich der Cursor gerade befindet.
8. Sie können Ihre Änderungen jederzeit speichern, ohne das Editor-Fenster zu schließen, indem Sie auf Apply klicken.
9. Klicken Sie auf OK, wenn Sie die Bearbeitung des Codes abgeschlossen haben.

Code mit Strukturansicht

Auf der Registerkarte "Strukturansicht" im Fenster "Snippet-Eigenschaften" werden Sie Schritt für Schritt durch die Erstellung von benutzerdefiniertem Code geführt. Dabei stehen vordefinierte Schlüsselwörter zur Auswahl.

1. Öffnen Sie Ihr Skript in Studio.
2. Fügen Sie Ihrem Skript die Snippet-Aktion hinzu und doppelklicken Sie darauf, um das Snippet-Fenster zu öffnen.
3. Klicken Sie unten auf der Registerkarte "Strukturansicht" auf das Pluszeichen .
4. Bild anzeigen

   

   Wählen Sie das Schlüsselwort aus, das Sie Ihrem Code hinzufügen möchten.
5. Klicken Sie auf das Schlüsselwort, das in der Liste auf der linken Seite des Fensters angezeigt wird, um seine Eigenschaften einzublenden.

6. Konfigurieren Sie die Eigenschaften des Schlüsselworts in der Liste auf der rechten Seite des Fensters. Sie können:

   • Wählen Sie jede Eigenschaft aus, um ihre Definition unterhalb des Bereichs auf der rechten Seite anzuzeigen.
   • Im Abschnitt Snippet-Schlüsselwörter auf dieser Seite finden Sie Details zur Konfiguration der einzelnen Befehle.
7. Fügen Sie nach Bedarf weitere Schlüsselwörter hinzu.
8. Sie können jederzeit auf die Registerkarte Text View klicken, um den Code im traditionellen Codierungsformat anzuzeigen.
9. Sie können Ihre Änderungen jederzeit speichern, ohne das Editor-Fenster zu schließen, indem Sie auf Apply klicken.
10. Klicken Sie auf OK, wenn Sie die Bearbeitung des Codes abgeschlossen haben.

Debuggen von Snippet-Code

Die Snippet-Aktion verfügt über einen eigenen Debugger, mit dem Sie den Code überprüfen können. Sie können Code nur auf der Registerkarte "Textansicht" debuggen.

Wenn Sie Ihren Code auf der Registerkarte "Strukturansicht" erstellt haben, wechseln Sie zur Registerkarte "Textansicht", um den Code zu debuggen. Wenn der Debugger Fehler feststellt, können Sie den betroffenen Codebereich anhand der angegebenen Zeilennummer identifizieren. Dann können Sie zur Registerkarte "Strukturansicht" zurückkehren, um das Problem zu beheben.

Es stehen weitere Optionen zum Debuggen zur Verfügung. Beispielsweise können Sie den Code Zeile für Zeile untersuchen und Haltepunkte verwenden. Sie können auch TRACE-Anweisungen im Snippet-Code verwenden, um beim Debuggen Text auszugeben. Diese Ausgabe kann hilfreich sein, um Probleme im Skript zu beheben.

1. Öffnen Sie in Studio ein Skript, das eine Snippet-Aktion enthält.
2. Doppelklicken Sie auf die Snippet-Aktion.
3. Add Snippet code on the Text View tab, if it doesn't already contain some.
4. On the right side of the Snippet editor window, click the Debugger tab.
5. Click the down-arrow button on the right side of the Debug icon and select Start.

6. If there are any syntax errors in the code, the Snippet editor window expands. All errors in the code appear in a pane at the bottom of the window. If there are no errors, skip to the next step.

   View image

   
   1. Correct the errors.
   2. When the errors have been corrected, click the Close or Clear Trace Output icons to close the error pane.
   3. Start the debugger again.
7. View the contents of the Variables as Text tab. The tab shows the variables and their values when all of the code has been executed if you didn't set a breakpoint.
8. You can select one or more lines in the snippet code and click the Comment out selected lines icon . This is helpful if you want to remove some code to see how the outcome of the debugging changes.
9. You can select one or more lines of commented-out code and click the Uncomment the selected lines icon to add those lines back into the snippet.

Snippet-Schlüsselwörter in der Strukturansicht

Schlüsselwörter oder Befehle sind Teil der Syntax der Anweisungen in der Snippet-Sprache. Sie sind vordefinierte Begriffe, die für spezifische Anwendungen in Skripten reserviert sind. Der Compiler erkennt das Schlüsselwort und führt das damit verknüpfte Verhalten durch. Wenn der Compiler zum Beispiel das Schlüsselwort ASSIGN sieht, erstellt er eine neue Variable mit dem Namen und Wert, die nach dem Schlüsselwort angegeben sind. Zum Beispiel: ASSIGN varName = 1

Da Schlüsselwörter reservierte Begriffe sind, können diese Wörter nicht als Identifikatoren für Objekte oder Variablen in Ihren Skripten verwendet werden.

Viele der Schlüsselwörter haben außerdem Studio Aktionen Führt einen Prozess innerhalb eines Studio-Skripts durch, wie z. B. das Erfassen von Kundendaten, Abspielen einer Nachricht oder Musik oder die Weiterleitung eines Kontakts zu einem Agenten. mit demselben Namen. Es gibt zum Beispiel ein Schlüsselwort IF und eine IF-Aktion. Beide erreichen dasselbe Verhalten in Ihrem Skript. Sie können Snippet-Aktionen mit benutzerdefiniertem Code verwenden, um die Anzahl der Aktionen in Ihren Skripten zu verringern.

In den folgenden Abschnitten werden die Optionen für Schlüsselwörter beschrieben, die auf der Registerkarte "Strukturansicht" zur Verfügung stehen. Diese Optionen umfassen die meisten Schlüsselwörter, die Sie in Snippets verwenden können. Eine vollständige Liste aller unterstützten Schlüsselwörter finden Sie im Referenz-Abschnitt.

Zuweisen

Beschreibung: ASSIGN-Anweisungen erstellen eine Variable mit dem Namen und dem Wert, die Sie angeben.

Studio-Aktion: Assign (Hilfeseite in CXone Studio: Assign)

Namenskonventionen: Beachten Sie beim Benennen von Variablen diese Richtlinien:

• Verwenden Sie alphanumerische Zeichen (a-z, A-Z, 0-9).

• Das erste Zeichen des Namens muss ein Buchstabe sein.
• Verwenden Sie den Unterstrich ( _ ) und das Dollarzeichen ( $ ) an einer beliebigen Stelle im Namen.
• Wenn das letzte Zeichen in einem Variablennamen ein Dollarzeichen ist, wird der Wert als Text behandelt.
• Verwenden Sie weder die Namen von vordefinierten Variablen noch reservierte Wörter.

Erfahren Sie mehr: Weitere Informationen über Variablen finden Sie auf der Hilfeseite Variablen. Weitere Informationen über das Schlüsselwort ASSIGN finden Sie auf der Seite Deklarierungsanweisungen.

Eigenschaften in der Strukturansicht

Auf der Registerkarte "Strukturansicht" wird ASSIGN als newvar="" dargestellt. Die folgenden Eigenschaften können konfiguriert werden:

• Comment: Fügen Sie einen Kommentar über die Variable hinzu.
• Line Number: Dies ist die Nummer der Zeile, auf der sich der Befehl im Editor befindet.
• Type: Dies ist der Datentyp Ein Informationsattribut, das definiert, wie es in einem Programm verwendet wird, z. B. integer (Zahlen, die manipuliert werden können) oder boolean (wahr/falsch)., der für den Wert zulässig ist.
• Value: Geben Sie den Wert ein, den Sie der Variablen zuweisen möchten. Sie können Variablen aufnehmen, indem Sie sie in geschweifte Klammern { } einschließen. Zum Beispiel {agentId}.
• Variable: Geben Sie einen neuen Namen für die Variable ein. Wenn Sie den Namen nicht ändern, wird der Standardname der Variablen beibehalten, das heißt newvar.

Beispiel

Sie können dieses Beispiel in der Strukturansicht anzeigen, indem Sie es kopieren und auf der Registerkarte "Textansicht" einfügen und dann auf die Registerkarte "Strukturansicht" klicken.

ASSIGN varName = value1
varName2 = value2

//Including the ASSIGN keyword is optional. 
//It's best practice to use this keyword every time you create a variable.
//When you use advanced search, you can quickly locate where a variable 
//is created if it includes this keyword. 

Pause

Beschreibung: Beendet eine Schleife sofort.

Syntax: BREAK

Details: Wenn die BREAK-Anweisung erreicht ist, wird die aktuelle Schleife sofort beendet. Das Skript fährt mit der Ausführung des Snippet-Codes unterhalb der Schleife fort, bis er abgeschlossen ist.

BREAK ist optional. Wenn es nicht enthalten ist, wird die Schleife fortgesetzt, bis die definierte Stoppbedingung erfüllt wird.

Funktion aufrufen

Ruft eine zuvor definierte Funktion auf.

Eigenschaften in der Strukturansicht

Auf der Registerkarte "Strukturansicht" wird "Funktion aufrufen" als newcall() angezeigt.

Die folgenden Eigenschaften können konfiguriert werden:

• Arguments: Geben Sie die Argumente ein, die an die Funktion übergeben werden sollen. Die Argumente werden im Funktionsnamen zwischen den Klammern angezeigt. Zum Beispiel functionA (var1, var2).
• Comment: Fügen Sie einen Kommentar über die Variable hinzu.
• Line Number: Dies ist die Nummer der Zeile, auf der sich der Befehl im Editor befindet.
• Name: Geben Sie den Namen der Funktion ein, die Sie aufrufen möchten.

Case

Beschreibung: Hiermit wird eine von mehreren möglichen Anweisungen definiert, die ausgeführt werden können. Wird mit SWITCH oder SELECT verwendet.

Syntax: variiert; siehe SWITCH oder SELECT

Studio-Aktion: (Hilfeseite in CXone Studio: Case)

Details:  CASE muss in einem Block mit Bedingungscode einer SWITCH- oder SELECT-Anweisung verwendet werden. Fügen Sie eine oder mehrere CASE-Anweisungen hinzu, um die möglichen Blöcke zu definieren, die das Skript ausführen kann. Mindestens eine CASE-Anweisung ist erforderlich.

Zugehörig: Fügen Sie eine DEFAULT-Anweisung ein, um die Case-Anweisung anzugeben, die verwendet werden soll, wenn keine der angegebenen CASE-Anweisungen zutrifft.

Kommentar

Blendet Text im Skript aus, damit er nicht vom Compiler verarbeitet wird.

Verwenden Sie Kommentare, um Ihr Skript zu dokumentieren. Sie können für jeden Teil Ihres Skripts Erläuterungen und Beschreibungen angeben, um das spätere Verständnis zu erleichtern.

Eigenschaften in der Strukturansicht

Auf der Registerkarte "Strukturansicht" wird Comment als // dargestellt.

Die folgenden Eigenschaften können konfiguriert werden:

• Comment: Fügen Sie einen Kommentar hinzu.
• Line Number: Dies ist die Nummer der Zeile, auf der sich der Befehl im Editor befindet.

Jedes Schlüsselwort, das in der Strukturansicht verfügbar ist, verfügt über eine Comment-Eigenschaft. So können Sie einen Kommentar zum jeweiligen Vorkommen des Schlüsselwortes hinzufügen. Verwenden Sie die Option Comment auf der Registerkarte "Strukturansicht", um einen allgemeinen Kommentar über das Snippet hinzuzufügen.

Funktion deklarieren

Beschreibung: Erstellt eine benutzerdefinierte Funktion.

Details: Deklarieren Sie eine Funktion, indem Sie ihr einen <name> geben und am Ende ein Paar offener und geschlossener Klammern einfügen. Zum Beispiel FUNCTION functionName(). Fügen Sie zwischen den Klammern wahlweise [parameters] hinzu. Mithilfe von Parametern können Sie Daten und aufgerufene Argumente an die Funktion übergeben oder aus ihr abrufen.

Namenskonventionen: Beachten Sie beim Benennen von Funktionen die folgenden Richtlinien:

• Verwenden Sie alphanumerische Zeichen (a-z, A-Z, 0-9).

• Das erste Zeichen des Namens muss ein Buchstabe sein.
• Verwenden Sie den Unterstrich ( _ ) und das Dollarzeichen ( $ ) an einer beliebigen Stelle im Namen.
• Verwenden Sie weder reservierte Wörter noch die Namen von integrierten Funktionen.

Erfahren Sie mehr: Weitere Informationen über Funktionen finden Sie auf der Hilfeseite Funktionen.

Eigenschaften in der Strukturansicht

Auf der Registerkarte "Strukturansicht" wird FUNCTION als FUNCTION newfunc() dargestellt.

Die folgenden Eigenschaften können konfiguriert werden:

• Arguments: Geben Sie die Argumente ein, die an die Funktion übergeben werden sollen. Die Argumente werden im Funktionsnamen zwischen den Klammern angezeigt. Zum Beispiel newfunc(var1, var2).
• Comment: Fügen Sie einen Kommentar über die Variable hinzu.
• Line Number: Dies ist die Nummer der Zeile, auf der sich der Befehl im Editor befindet.
• Name: Geben Sie den Namen der Funktion ein.

Zum Abschließen von FUNCTION klicken Sie mit der rechten Maustaste auf SWITCH 0 und fügen Sie das Schlüsselwort CASE für jede Bedingung hinzu, die das Skript auswerten soll. Fügen Sie eine DEFAULT-Bedingung hinzu, um festzulegen, wie das Skript vorgeht, wenn keine der definierten CASE-Optionen zutreffen. Konfigurieren Sie alle Vorkommen von CASE und das Schlüsselwort DEFAULT.

Beispiel

Sie können dieses Beispiel in der Strukturansicht anzeigen, indem Sie es kopieren und auf der Registerkarte "Textansicht" einfügen und dann auf die Registerkarte "Strukturansicht" klicken.

FUNCTION TimerRound(Timer)
{
  IF Timer = "-1"
  {
    ASSIGN Timer = Timer
  }
  ELSE
  {
    ASSIGN PeriodLocation = Timer.indexof('.')
	IF PeriodLocation = 0
	{
	  ASSIGN Timer = Timer
	}
	ELSE
	{
	    ASSIGN DataLength = Timer.length
	    IF DataLength - PeriodLocation <= 2
	        {
	          ASSIGN Timer = Timer
            }   
	    ELSE
	     {
            ASSIGN DigitCheck = Timer.substr(PeriodLocation + 3, PeriodLocation + 3)
            IF DigitCheck >=5 && DigitCheck <= 9
               {
                  ASSIGN Timer = Timer + .01
               }
            ELSE
              {
                 ASSIGN Timer = Timer
              }
		
            ASSIGN Timer = Timer.substr(1, PeriodLocation + 2)
         }
      }
   }
  
   TRACE "{Timer}"
   RETURN Timer
}

IF TEST = 1
   {
      ASSIGN DC1 = "1.931876668494874"
   }   

   ASSIGN DC1 = TimerRound(DC1)

Standard

Beschreibung: Definiert den CASE-Block, der verwendet wird, wenn keine der angegebenen CASE-Anweisungen zutrifft. Wird mit SWITCH und SELECT verwendet.

Syntax: variiert, siehe SWITCH oder SELECT

Details: DEFAULT muss mit SWITCH- oder SELECT-Blöcken verwendet werden und es muss mindestens eine CASE-Anweisung vorhanden sein. DEFAULT kann nicht alleine verwendet werden. DEFAULT ist immer optional. Dies muss die letzte Klausel in der Liste der CASE-Anweisungen sein.

Für

Beschreibung: Hiermit wird eine Anweisung oder eine Reihe von Anweisungen so oft wie festgelegt wiederholt.

Eigenschaften in der Strukturansicht

Auf der Registerkarte "Strukturansicht" wird FOR  als FOR i = 1 to 10 dargestellt.

Die folgenden Eigenschaften können konfiguriert werden:

• Comment: Fügen Sie einen Kommentar über die FOR Schleife hinzu.

• EndValue: Geben Sie den Index-Endwert ein. Der Standard ist 10.

• Iterator: Geben Sie den Namen der Variablen ein, die den aktuellen Schleifenindex enthält.

• Line Number: Dies ist die Nummer der Zeile, auf der sich der Befehl im Editor befindet.
• StartValue: Geben Sie den Index-Startwert ein. Der Standard ist 1.

Zum Abschließen von FOR klicken Sie mit der rechten Maustaste auf FOR i = 1 to 10 und fügen Sie die Schlüsselwörter und Verhalten hinzu, die das Skript ausführen soll.

Beispiele

Sie können diese Beispiele in der Strukturansicht anzeigen, indem Sie sie kopieren und auf der Registerkarte "Textansicht" einfügen und dann auf die Registerkarte "Strukturansicht" klicken.

IF TEST = 1
{
  ASSIGN Names = "Wes|Nate|Dan|Clay"
  ASSIGN EyeColors = "Blue|Blue|Brown|Brown"
  ASSIGN Signs = "Aquarius|Aries|Pisces|Leo"
  ASSIGN Foods = "Spagetti|Pizza|Sushi|Deep Fried Twinkies"
}

DYNAMIC Persons

ASSIGN PeopleCount = Names.size

FOR i = 1 TO PeopleCount
{
  ASSIGN Persons[i].Name = "{Names[i]}"
  ASSIGN Persons[i].Eyecolor = "{EyeColors[i]}"
  ASSIGN Persons[i].Sign = "{Signs[i]}"
  ASSIGN Persons[i].Food = "{Foods[i]}"
}

FOR i=1 TO 9
{
	a = "{a}{i}"
}
//Result: a="123456789"


FOR i=9 TO 1
{
	b = "{b}{i}"
}
//Result: b="987654321"

ForEach

Beschreibung: wiederholt eine Schleife einmal für jedes Element im angegebenen String-Array.

Eigenschaften in der Strukturansicht

Auf der Registerkarte "Strukturansicht" wird FOREACH als FOREACH i in array dargestellt.

Die folgenden Eigenschaften können konfiguriert werden:

• ArrayName: Dies ist der Name der Variablen, die das Array enthält, auf das das Skript die definierten Verhaltensweisen anwenden soll.
• Comment: Fügen Sie einen Kommentar über die FOREACH Schleife hinzu.

• Iterator: Geben Sie den Namen der Variablen ein, die das aktuelle Array-Element enthält.

• Line Number: Dies ist die Nummer der Zeile, auf der sich der Befehl im Editor befindet.

Zum Abschließen von FOREACH klicken Sie mit der rechten Maustaste auf FOREACH i in array und fügen Sie die Schlüsselwörter und Verhalten hinzu, die angeben, wie das Skript die einzelnen Elemente im angegebenen Array verarbeiten soll.

Beispiel

Sie können dieses Beispiel in der Strukturansicht anzeigen, indem Sie es kopieren und auf der Registerkarte "Textansicht" einfügen und dann auf die Registerkarte "Strukturansicht" klicken.

IF TEST = 1 
{
	ASSIGN Names="Odin|Freya|Thor|Loki"
}
ASSIGN SubCounter=1
FOREACH Name IN Names
{
	IF Name = "Odin" |  Name = "Freya"
	{
		ASSIGN NewNames[SubCounter]= "{Name}"

		ASSIGN SubCounter=SubCounter + 1

	}
}

If

Beschreibung: Wertet einen Ausdruck aus und folgt einer Verzweigung, die sich nach dem Ergebnis der Auswertung richtet.

Studio-Aktion: If (Hilfeseite in CXone Studio: If)

Eigenschaften in der Strukturansicht

Auf der Registerkarte "Strukturansicht" wird IF als >IF 0 mit >True und False darunter dargestellt. >IF definiert den auszuwertenden Ausdruck. >True definiert, was geschieht, wenn der Ausdruck als "true" ausgewertet wird. >False definiert, was geschieht, wenn der Ausdruck als "false" ausgewertet wird.

Die folgenden Eigenschaften können konfiguriert werden:

• Comment: Fügen Sie einen Kommentar über die IF-Anweisung hinzu.
• Expression: Geben Sie die Bedingung ein, die das Skript auswerten soll.
• Line Number: Dies ist die Nummer der Zeile, auf der sich der Befehl im Editor befindet.

Zum Abschließen der IF-Anweisung klicken Sie mit der rechten Maustaste auf True und False . Wählen Sie dann das Schlüsselwort oder Verhalten aus, das das Skript ausführen soll, je nachdem, wie der Expression ausgewertet wird. Es ist nicht erforderlich, Optionen für True und False anzugeben. Sie können mehr als ein Schlüsselwort oder Verhalten hinzufügen. Konfigurieren Sie die ausgewählten Schlüsselwörter oder Verhalten nach Bedarf.

Beispiel

Sie können dieses Beispiel in der Strukturansicht anzeigen, indem Sie es kopieren und auf der Registerkarte "Textansicht" einfügen und dann auf die Registerkarte "Strukturansicht" klicken.

IF TEST = 1
   {
      ASSIGN contactID = "123456780"
      ASSIGN customerName = "XYZ International"
      ASSIGN CBWindowStart = #"{date} 8:00 AM"
      ASSIGN CBWindowEnd = #"{date} 4:30 PM"
   }

//String Comparison

IF customerName = "ABC Corporation"
   {
      ASSIGN contractLevel = "Gold"
   }
   ELSE
      {
         ASSIGN contractLevel = "Silver"
      }

//Numeric Comparision

IF contactID % 10 = 0
   {
      ASSIGN logCall = 1
   }
   ELSE
      {
         ASSIGN logCall = 0
      }

//DateTime Comparison

ASSIGN myTime = #"{time}"

IF myTime >= CBWindowStart && myTime  <= CBWindowEnd
   {
      ASSIGN offerCallback = "True"
   }
   ELSE
      {
         ASSIGN offerCallback = "False"
      }

Wiederholen

Beschreibung: Führt die angegebenen Befehle so oft wie angegeben aus.

Eigenschaften in der Strukturansicht

Auf der Registerkarte "Strukturansicht" wird REPEAT als REPEAT 0 dargestellt.

Die folgenden Eigenschaften können konfiguriert werden:

• Comment: Fügen Sie einen Kommentar über die Wiederholung hinzu.
• Line Number: Dies ist die Nummer der Zeile, auf der sich der Befehl im Editor befindet.

• Repeat: Geben Sie einen Ausdruck ein, der als numerischer Wert ausgewertet wird, um festzulegen, wie oft die angegebenen Verhaltensweisen wiederholt werden sollen.

Zum Abschließen von REPEAT klicken Sie mit der rechten Maustaste auf REPEAT 0 und wählen Sie das Verhalten aus, das das Skript wiederholen soll. Sie können mehr als ein Verhalten hinzufügen. Konfigurieren Sie jedes ausgewählte Verhalten.

Beispiel

Sie können dieses Beispiel in der Strukturansicht anzeigen, indem Sie es kopieren und auf der Registerkarte "Textansicht" einfügen und dann auf die Registerkarte "Strukturansicht" klicken.

REPEAT 10
{
	phone = "{phone}{random(10)}"
}	

Return

Beschreibung: Beendet eine Funktion und übergibt wahlweise eine Variable von der Funktion an das Skript. Zur Verwendung mit FUNCTION -Anweisungen.

Syntax: RETURNoderRETURN <var>

Studio-Aktion: Return (Hilfeseite in CXone Studio: Return)

Details: Muss im Code einer Funktionsdeklaration verwendet werden. Fügen Sie einen Variablennamen <var> nach dem Schlüsselwort RETURN hinzu, um Informationen an das Skript zurückzugeben.

Auswählen

Beschreibung: Führt basierend auf dem ersten Ausdruck, der als "true" ausgewertet wird, einen Satz mit Befehlen aus.

Eigenschaften in der Strukturansicht

Auf der Registerkarte "Strukturansicht" wird SELECT als SELECT 0 dargestellt.

Die folgenden Eigenschaften können konfiguriert werden:

• Comment: Fügen Sie einen Kommentar über SELECT hinzu.
• Line Number: Dies ist die Nummer der Zeile, auf der sich der Befehl im Editor befindet.

Zum Abschließen von SELECT klicken Sie mit der rechten Maustaste auf SELECT 0 und fügen Sie das Schlüsselwort CASE für jeden Ausdruck hinzu, den das Skript auswerten soll. Fügen Sie eine DEFAULT -Bedingung hinzu, um festzulegen, wie das Skript vorgeht, wenn keine der definierten CASE -Optionen zutreffen. Konfigurieren Sie alle Vorkommen von CASE und das Schlüsselwort DEFAULT .

Beispiel

Sie können dieses Beispiel in der Strukturansicht anzeigen, indem Sie es kopieren und auf der Registerkarte "Textansicht" einfügen und dann auf die Registerkarte "Strukturansicht" klicken.

SELECT
{
	CASE name="Odin" { agentid = 123 }
	CASE name="Frigg" { agentid = 345 }
	CASE name.length = 0
	 {
	   ASSIGN agentid = -1
	   ASSIGN error = "Invalid name"
	 }
	DEFAULT { ASSIGN agentid = 999 }
} 

Wechseln

Beschreibung: Wertet die angegebene Variable aus und führt die Aktion aus, die von der entsprechenden CASE-Anweisung definiert wird.

Details:  SWITCH vergleicht den Wert einer Variablen mit dem Literalwert einer jeden CASE-Anweisung. Wenn eine übereinstimmende CASE -Anweisung gefunden wird, wird SWITCH ausgeführt und folgt der Verzweigung zu dem Code in geschweiften Klammern { ... }, der zur entsprechenden CASE-Anweisung gehört.

Mindestens eine CASE-Anweisung wird erwartet. Alle CASE-Anweisungen müssen denselben Typ von Literalwert haben. Die erste CASE-Anweisung bestimmt den Typ für die verbleibenden CASE-Anweisungen. Wenn eine CASE-Anweisung einen anderen Typ als die erste CASE-Anweisung hat, tritt ein Kompilierungsfehler auf. Die folgenden Beispiele sind alle gültige Literalwerte:

• CASE "john"
• CASE 512
• CASE #"5/15/2050"
• CASE #"6/1/2050 7:00am"
• CASE #"7am"

Beispiel:

IF TEST = 1
{
  ASSIGN MyDate = "07/03/2023" //This date falls on a Monday
}
ASSIGN MyDow = MyDate.asdatedow
SWITCH MyDow
{
  CASE 0   { ASSIGN NewToday = "Sunday"  }
  CASE 1   { ASSIGN NewToday = "Monday"  }
  CASE 2   { ASSIGN NewToday = "Tuesday" }
  CASE 3   { ASSIGN NewToday = "Wednesday" }
  CASE 4   { ASSIGN NewToday = "Thursday" }
  CASE 5   { ASSIGN NewToday = "Friday"  }
  CASE 6   { ASSIGN NewToday = "Saturday"   }
}

Anwendungsfall: SWITCH ermöglicht spezifische Ergebnisse, je nach dem Inhalt der angegebenen Variablen. Beispielsweise kann das Skript eine Variable auswerten, die Vorwahlen enthält. Sie können eine CASE-Anweisung für jede mögliche Vorwahl definieren und das Skript so konfigurieren, dass ein Wert für jede state-Variable hinzugefügt wird, die dem Bundesstaat entspricht, zu dem die Vorwahl gehört. Beispiel:

SWITCH areaCode
{
	CASE 603 { state =  "New Hampshire" }
	CASE 614 { state =  "Ohio" }
	CASE 628 { state =  "California" }
	CASE 646 { state =  "New York" }
	CASE 667 { state =  "Maryland" }
}

Sie können dieses Beispiel in der Strukturansicht anzeigen, indem Sie es kopieren und auf der Registerkarte "Textansicht" einfügen und dann auf die Registerkarte "Strukturansicht" klicken.

Eigenschaften in der Strukturansicht

Auf der Registerkarte "Strukturansicht" wird SWITCH  als SWITCH 0 dargestellt.

Die folgenden Eigenschaften können konfiguriert werden:

• Comment: Fügen Sie einen Kommentar über SWITCH hinzu.

• Expression:

• Line Number: Dies ist die Nummer der Zeile, auf der sich der Befehl im Editor befindet.

Zum Abschließen von SWITCH klicken Sie mit der rechten Maustaste auf SWITCH 0 und fügen Sie das Schlüsselwort CASE für jede Bedingung hinzu, die das Skript auswerten soll. Fügen Sie eine DEFAULT -Bedingung hinzu, um festzulegen, wie das Skript vorgeht, wenn keine der definierten CASE -Optionen zutreffen. Konfigurieren Sie alle Vorkommen von CASE und das Schlüsselwort DEFAULT .

Trace

Beschreibung: Gibt Text im Ergebnisbereich des Snippet editor-Fensters aus, wenn Sie den Debugger auf der Registerkarte "Textansicht" verwenden.

Syntax: TRACE "<value>"

Details: Fügen Sie ein TRACE-Schlüsselwort mit jedem "<value>" hinzu, der im Ergebnisbereich des Snippet editor-Fensters angezeigt werden soll, wenn Sie den Debugger verwenden. Der <value> kann ein Variablenname sein. TRACE ist hilfreich, wenn Sie Probleme mit Ihrem Code beheben oder wenn Sie den Ablauf Ihres Skripts nachverfolgen möchten.

Dieses Schlüsselwort ist nur zur Verwendung in Snippet-Aktionen vorgesehen. TRACE-Schlüsselwörter können bedenkenlos in Ihren Snippets verbleiben. Zur Laufzeit werden sie außerhalb des Debuggers im Snippet editor-Fenster ignoriert.

Eigenschaften in der Strukturansicht

Auf der Registerkarte "Strukturansicht" können für TRACE  die folgenden Eigenschaften konfiguriert werden:

• AllowEscapes: Bei der Einstellung true können Sie eine Escape-Sequenz einbetten, die mit einem Schrägstrich (\) beginnt. Der Standard ist false.
• Comment: Fügen Sie einen Kommentar über den Trace hinzu.
• Expression: Der Text, der im Ergebnisbereich ausgegeben werden soll. Sie können Variablen aufnehmen, indem Sie sie in geschweifte Klammern { } einschließen. Zum Beispiel {agentId}.
• Line Number: Dies ist die Nummer der Zeile, auf der sich der Befehl im Editor befindet.

Beispiel

Sie können dieses Beispiel in der Strukturansicht anzeigen, indem Sie es kopieren und auf der Registerkarte "Textansicht" einfügen und dann auf die Registerkarte "Strukturansicht" klicken.

TRACE "this is trace text"
//The text you specify with TRACE appears 
//In the results window when you use the 
//Debugger on the Text View tab. 

Beschreibung: Hiermit können Sie eine Proxy-DLL für einen SOAP-Webdienst zur Verwendung im Snippet einschließen. Die DLL muss von WISDL von NICE CXone kompiliert werden.

Syntax: USES "<proxy>.dll"

Studio-Aktion: Uses (Hilfeseite in CXone Studio: Uses)

Details: Zur Verwendung einer USES-Anweisung muss sich die Proxy-DLL im Stammordner des Dateiservers Ihres Mandanten Eine übergeordnete organisatorische Gruppierung, die Sie für die technische Unterstützung und Abrechnung und außerdem zur Bearbeitung von globalen Einstellungen in Ihrer CXone Umgebung einsetzen können. befinden. Sie können die Dateien für Ihre Mandanten auf der Seite "ACD-Dateien durchsuchen" in CXone anzeigen.

Erfahren Sie mehr: Weitere Informationen zur Verwendung von Webdienst-Proxys mit Studio-Skripten finden Sie auf der Hilfeseite API-Aufrufe von SNIPPET-Aktionen.

Eigenschaften in der Strukturansicht

Auf der Registerkarte "Strukturansicht" wird "Uses" als USES "" angezeigt.

Die folgenden Eigenschaften können konfiguriert werden:

• Comment: Fügen Sie einen Kommentar über dieses Schlüsselwort hinzu.
• FileName: Fügen Sie den Namen der Proxy-DLL-Datei hinzu, die Sie im Snippet verwenden möchten.
• Line Number: Dies ist die Nummer der Zeile, auf der sich der Befehl im Editor befindet.

Jedes Schlüsselwort verfügt über eine Comment-Eigenschaft. Damit können Sie einen Kommentar über dieses Schlüsselwort hinzufügen. Verwenden Sie die Option Comment, um einen Kommentar hinzuzufügen, der nicht zu einer bestimmten Eigenschaft gehört.