カスタムコードのスニペット

このヘルプページの情報は、CXone StudioとDesktop Studioの両方に適用されます。

スクリプトによっては、Studioアクションのみでは提供できない複雑な操作が必要とされます。Studioを使用すると、スクリプトにカスタムコードを追加できます。これにより、組織のニーズに合わせてスニペットをカスタマイズすることができます。

カスタムコードの作成にはスクリプトやプログラミングの知識が必要です。Studioは、Snippetというプログラミング言語を使用します。この言語はStudioで使用するためにNICE CXoneによって開発されたものです。この言語の使い方を学べるよう、オンラインヘルプに完全なテクニカルリファレンスガイドが用意されています。

スニペットに関する重要ポイント

コードスニペットは、スクリプトの構成と効率を向上させるのに役立ちます。いつ、どのように実行するか、および実行されるプロセスをさらに効果的にコントロールできるようになります。独自の変数やオブジェクトを作成し、IF、FOR、FOREACHなどのステートメントを使用してプログラミングロジックを追加できます。
製品や機能によってはスニペットを必要としますが、必要ない場合でもスクリプトで使用することができます。
製品や機能でコードスニペットが必要な場合、含める必要があるスニペットに関する詳細情報はオンラインヘルプに提供されています。スクリプトでのコードスニペットの使い方を示すため、スクリプトの例も含まれています。製品や機能を実装するには、追加のスクリプトが必要になる場合があります。
Snippetスクリプト言語は.NETフレームワークに基づいて構築されています。この言語はサーバー側で実行され、C#やVisual Basic .NETと同様にMSIL（Microsoft Intermediate Language）にコンパイルされます。

スニペットアクション

スクリプトにカスタムコードを追加するには、Snippetアクションが必要です。このアクションをダブルクリックするとエディターウィンドウが開き、カスタムコードを追加できます。エディターウィンドウではコードをデバッグすることもできます。場合によってはスクリプトに複数のSnippetアクションを含める必要があります。複数のアクションを使用する場合、各アクションの追加のCaptionフィールドをその目的がわかるようなフレーズで更新してください。

Snippetアクションの配置は重要です。Snippetが変数に値を代入する場合、その値を必要とするアクションの前にこれを配置しなければなりません。一方、Snippetに、受け取った値に基づいて行われる意思決定コードが含まれる場合、Snippetはその値を提供するアクションの後に配置しなければなりません。

スニペットとアクションの比較

スニペットで行えることのいくつかは、Studioアクションを使って行うことも可能です。たとえば、IFおよびFORステートメント用のアクションがあります。また、カスタム変数を作成して値を代入するために使用できるASSIGNアクションもあります。これらのアクションを使ってスクリプトにその機能を追加することも可能です。しかし、スニペットを使用する方がより効率的です。

スニペットにコードを配置することで、スクリプトが整理されてわかりやすくなります。これにより、スクリプトの作成作業がより簡単で効率的なものになります。常にスニペットで変数を宣言する習慣をつけることで、今後特定の宣言を探す必要が生じたときに、検索する場所を少なくすることができます。

スクリプトにカスタムコードを追加する

Snippetアクションを使用すると、スクリプトにカスタムコードを追加できます。このアクションは、ツールタブのデフォルトパレットにあるアドバンスセクションにあります。

Studioで、スクリプトを開きます。
Snippetアクションをスクリプト内の必要な場所に配置し、他のアクションに接続します。
アクションをダブルクリックして、エディターウィンドウを開きます。ここでコードを追加できます。
コードの追加に使用するタブをクリックします。各タブにコードを追加するさまざまな方法が提供されています。以下のタブがあります。
- ツリービュー：アプリケーションで提供されるリストにあるコマンドを使用して、カスタムコードを作成できます。コマンドを選択し、これに必要な詳細を指定して設定します。
  
  スニペットエディターウィンドウのツリービュータブの画像を見る
- テキストビュー：手作業でカスタムコードを入力できます。このオプションには基本的なスクリプト作成の知識が必要です。
  
  スニペットエディターウィンドウのテキストビュータブの画像を見る
必要に応じてコードをデバッグします。
Applyをクリックすると、エディターウィンドウを閉じずにいつでも変更内容を保存することができます。
コードの編集が終了したら、OKをクリックします。

テキストビューを使ったコーディング

スニペットウィンドウのテキストビュータブを使用して、Snippetコードを手作業で作成できます。この言語の使い方を学べるよう、オンラインヘルプに完全なリファレンスガイドが用意されています。

Studioで、スクリプトを開きます。
スクリプトにSnippetアクションを追加してダブルクリックし、スニペットウィンドウを開きます。
ツリービュータブの左側にコードを入力します。コードは手動で入力するか、このヘルプサイトや別のスクリプトなど他のソースからコピーして貼り付けることができます。
Tree Viewタブをクリックすると、あらかじめ定義されたキーワードからコードをいつでも追加できます。上矢印ボタンと下矢印ボタンを使って、キーワードに関連するコードをスクリプト内の別の箇所に移動させることができます。
現在のコードの構文が正しいかどうかを確認するには、Check Syntaxアイコンをクリックします。エラーがなければ、テキストビュータブの下部にあるツールバーのステータスフィールドに Okayステータスが表示されます。エラーがある場合、エラーに関するポップアップメッセージが開き、ツールバーのステータスフィールドにもメッセージが表示されます。たとえば、「Error at line 4」などと表示されます。
現在カーソルのある行をコメントに変換するには、Commentアイコンをクリックします。
現在カーソルのある行からコメント文字を削除するには、Uncommentアイコンをクリックします。
Applyをクリックすると、エディターウィンドウを閉じずにいつでも変更内容を保存することができます。
コードの編集が終了したら、OKをクリックします。

ツリービューを使ったコーディング

スニペットプロパティウィンドウのツリービュータブは、カスタムコードの作成プロセスをガイドします。あらかじめ定義されているキーワードのセットから選択することができます。

Studioで、スクリプトを開きます。
スクリプトにSnippetアクションを追加してダブルクリックし、スニペットウィンドウを開きます。
ツリービュータブの下部にあるプラスのアイコンをクリックします。
画像の表示

コードに追加するキーワードを選択します。
ウィンドウの左側のリストに表示されるキーワードをクリックして、そのプロパティを表示します。
ウィンドウの右側のリストで、キーワードのプロパティを設定します。次が可能です：
- 各プロパティを選択して、右側ペインの下のスペースでプロパティの定義を確認します。
- このページのスニペットキーワードセクションを参照し、各コマンドの設定についての詳細を確認します。
必要に応じてキーワードをさらに追加します。
Text Viewタブを随時クリックして、従来のコーディング形式で記述されたコードを確認します。
Applyをクリックすると、エディターウィンドウを閉じずにいつでも変更内容を保存することができます。
コードの編集が終了したら、OKをクリックします。

スニペットコードをデバッグする

Snippetアクションには独自のデバッガがあり、これを使ってコードをチェックできます。コードのデバッグはテキストビュータブでのみ可能です。

ツリービュータブでコードを作成した場合、テキストビュータブに切り替えるとデバッガを使えるようになります。デバッガで問題が見つかった場合、指定された行番号に基づいてコード内の問題がある箇所を特定してください。その後、ツリービュータブに戻って問題を修正することができます。

1行ずつコードをステップスルーしたり、ブレークポイントを使用するなど、追加のデバッグオプションを利用できます。また、スニペットコードでTRACEステートメントを使用して、デバッグ時にテキストを出力することもできます。この出力はスクリプトに含まれる問題を修正するために役立ちます。

Studioで、Snippetアクションを含むスクリプトを開きます。
Snippetアクションをダブルクリックします。
Add Snippet code on the Text View tab, if it doesn't already contain some.
On the right side of the Snippet editor window, click the Debugger tab.
Click the down-arrow button on the right side of the Debug icon and select Start.
If there are any syntax errors in the code, the Snippet editor window expands. All errors in the code appear in a pane at the bottom of the window. If there are no errors, skip to the next step.

View image
1. Correct the errors.
2. When the errors have been corrected, click the Close or Clear Trace Output icons to close the error pane.
3. Start the debugger again.
View the contents of the Variables as Text tab. The tab shows the variables and their values when all of the code has been executed if you didn't set a breakpoint.
You can select one or more lines in the snippet code and click the Comment out selected lines icon . This is helpful if you want to remove some code to see how the outcome of the debugging changes.
You can select one or more lines of commented-out code and click the Uncomment the selected lines icon to add those lines back into the snippet.

ツリービューのスニペットキーワード

キーワードまたはコマンドは、Snippet語のステートメントの構文の一部です。これらは、スクリプト内の特定の用途に予約されている定義済みの用語です。コンパイラはキーワードを認識し、それに関連する行動を実行します。たとえば、コンパイラはASSIGNキーワードを見つけると、キーワードの後に指定された名前と値を持つ新しい変数を作成します。例：ASSIGN varName = 1

キーワードは予約語であるため、これらの単語をスクリプト内のオブジェクトや変数の識別子として使用することはできません。

多くのキーワードには同じ名前のStudioアクション顧客データの収集、メッセージや音楽の再生、エージェントへの連絡先のルーティングなど、Studioスクリプト内のプロセスを実行します。もあります。たとえば、IFキーワードとIFアクションがあります。どちらもスクリプト内で同じ動作を実現します。カスタムコードでSnippetアクションを使用すると、スクリプト内のアクションの数を減らすことができます。

以下のセクションでは、ツリービュータブで利用できるキーワードオプションについて説明します。これらのオプションにはスニペットで使用できるキーワードのほとんどが含まれています。サポートされるキーワードの完全なリストは、リファレンスセクションにあります。

割り当て

説明：ASSIGNステートメントは、指定された名前と値で変数を作成します。

Studioアクション：Assign (CXone Studio：Assignのヘルプページを参照)

命名のガイドライン：変数の名前を付けるときは、以下のガイドラインに従ってください。

英数字（a-z, A-Z, 0-9）を使用できます。
名前の最初の文字はアルファベットでなければなりません。
名前の任意の場所に、アンダースコア文字（_）とドル記号（$）を使用できます。
変数名の最後の文字がドル記号の場合、その値はテキストとして扱われます。
あらかじめ定義された変数名または予約語は使用しないでください。

詳細：変数についての詳細は、変数ヘルプページを参照してください。ASSIGNキーワードについての詳細は、宣言ステートメントページを参照してください。

ツリービューのプロパティ

ツリービュータブでは、ASSIGNがnewvar=""のように表示されます。設定するプロパティは以下のとおりです：

Comment：変数に関するコメントを追加します。
Line Number：エディターでのコマンドの行番号です。
Type：値に許可されるデータ型整数（操作可能な数値）、ブール値（真／偽）など、プログラムでの使用方法を定義する情報の属性。。
Value：変数に代入する値を入力します。変数を中括弧で囲んで含めることができます{ }。例えば、 {agentId} 。
Variable：変数の新しい名前を入力します。これを変更しない場合、変数名はデフォルトのnewvarのままになります。

例

この例をツリービューで見るには、テキストビュータブにコピー＆ペーストしてから、ツリービュータブをクリックします。

ASSIGN varName = value1
varName2 = value2

//Including the ASSIGN keyword is optional. 
//It's best practice to use this keyword every time you create a variable.
//When you use advanced search, you can quickly locate where a variable 
//is created if it includes this keyword.

休憩

説明：ループを直ちに終了します。

構文：BREAK

詳細はこちら：BREAKステートメントに達すると、現在のループは直ちに終了します。スクリプトは、ループの下のスニペットコードを完了するまで実行し続けます。

BREAKはオプションです。これが含まれていない場合、ループは定義された停止条件が満たされるまで続行します。

呼び出し関数

以前に定義された関数を呼び出します。

ツリービューのプロパティ

ツリービュータブでは、呼び出し関数がnewcall()のように表示されます。

設定するプロパティは以下のとおりです：

Arguments：関数に渡す必要のある引数を入力します。引数は関数名の括弧の間に表示されます。例えば、 functionA (var1, var2) 。
Comment：変数に関するコメントを追加します。
Line Number：コマンドの行番号がエディターに表示されます。
Name：呼び出す関数の名前を入力します。

ケース

説明：実行できるステートメントセットの1つを定義します。SWITCHまたはSELECTと一緒に使用されます。

構文：はさまざまです。SWITCHまたはSELECTを参照してください。

Studioアクション： (CXone Studio：Caseのヘルプページを参照)

詳細：CASEは、SWITCHまたはSELECTステートメントの条件コードブロック内で使用しなければなりません。スクリプトが実行可能なブロックを定義するために、1つ以上のCASEステートメントを追加します。少なくとも1つのCASEが必要です。

関連事項： 指定されたCASEステートメントがどれも適用されない場合に使用されるケースを定義するDEFAULTステートメントを含めます。

コンパイラで処理されないようにスクリプト内のテキストを隠します。

スクリプトの文書化にはコメントを使用します。スクリプトの各部分に説明や解説を付けることで、後で理解しやすくなります。

ツリービューのプロパティ

ツリービュータブでは、Comment が//のように表示されます。

設定するプロパティは以下のとおりです：

Comment：コメントを追加します。
Line Number：コマンドの行番号がエディターに表示されます。

ツリービューで利用可能な各キーワードには、Commentプロパティがあります。これにより、キーワードの特定のインスタンスに関するコメントを追加することができます。スニペットに関する一般的なコメントを追加するには、ツリービュータブのCommentオプションを使用します。

宣言関数

説明：カスタム関数を作成します。

詳細：関数を宣言するには<name>を指定し、最後に開閉の括弧を付けます。例えば、 FUNCTION functionName() 。括弧の間にオプションで[parameters]を追加できます。パラメーターによって、データ（引数と呼ばれます）を関数の内外に渡すことができます。

命名のガイドライン：関数に名前を付ける場合は、以下のガイドラインに従ってください。

英数字（a-z, A-Z, 0-9）を使用できます。
名前の最初の文字はアルファベットでなければなりません。
名前の任意の場所に、アンダースコア文字（_）とドル記号（$）を使用できます。
予約語や組み込み関数の名前は使用しないでください。

詳細：関数についての詳細は、関数ヘルプページを参照してください。

ツリービューのプロパティ

ツリービュータブでは、FUNCTIONがFUNCTION newfunc()のように表示されます。

設定するプロパティは以下のとおりです：

Arguments：関数に渡す引数を入力します。引数は関数名の括弧の間に表示されます。例えば、 newfunc(var1, var2) 。
Comment：変数に関するコメントを追加します。
Line Number：コマンドの行番号がエディターに表示されます。
Name：関数の名前を入力します。

FUNCTIONを完成させるには、SWITCH 0を右クリックし、スクリプトで評価する各条件に対してCASEキーワードを追加します。DEFAULT条件を追加して、定義されたCASEオプションのどれも適用されない場合のスクリプトの動作を指定します。各CASEとDEFAULTキーワードを設定します。

例

この例をツリービューで見るには、テキストビュータブにコピー＆ペーストしてから、ツリービュータブをクリックします。

FUNCTION TimerRound(Timer)
{
  IF Timer = "-1"
  {
    ASSIGN Timer = Timer
  }
  ELSE
  {
    ASSIGN PeriodLocation = Timer.indexof('.')
	IF PeriodLocation = 0
	{
	  ASSIGN Timer = Timer
	}
	ELSE
	{
	    ASSIGN DataLength = Timer.length
	    IF DataLength - PeriodLocation <= 2
	        {
	          ASSIGN Timer = Timer
            }   
	    ELSE
	     {
            ASSIGN DigitCheck = Timer.substr(PeriodLocation + 3, PeriodLocation + 3)
            IF DigitCheck >=5 && DigitCheck <= 9
               {
                  ASSIGN Timer = Timer + .01
               }
            ELSE
              {
                 ASSIGN Timer = Timer
              }
		
            ASSIGN Timer = Timer.substr(1, PeriodLocation + 2)
         }
      }
   }
  
   TRACE "{Timer}"
   RETURN Timer
}

IF TEST = 1
   {
      ASSIGN DC1 = "1.931876668494874"
   }   

   ASSIGN DC1 = TimerRound(DC1)

デフォルト

説明：指定されたCASEのどれも適用されない場合に使われるCASEブロックを定義します。SWITCHおよびSELECTと一緒に使用されます。

構文：さまざまです。SWITCHまたはSELECTを参照してください。

詳細：DEFAULTは、SWITCHまたはSELECTブロックとともに使用し、CASEステートメントが少なくとも1つ必要です。DEFAULTを単独で使用することはできません。DEFAULTは常にオプションです。これは、CASEステートメントのリストの最後の句でなければなりません。

対象：

説明：ステートメントまたは一連のステートメントを特定の回数繰り返します。

ツリービューのプロパティ

ツリービュータブでは、FOR がFOR i = 1 to 10のように表示されます。

設定するプロパティは以下のとおりです：

Comment：FOR ループに関するコメントを追加します。
EndValue：終了のインデックス値を入力します。デフォルトは10です。
Iterator：現在のループインデックスを保持する変数の名前を入力します。
Line Number：コマンドの行番号がエディターに表示されます。
StartValue：開始のインデックス値を入力します。デフォルトは1です。

FORを完成させるには、FOR i = 1 to 10を右クリックし、キーワードとスクリプトに実行させる動作を追加します。

例

これらの例をツリービューで見るには、テキストビュータブにコピー＆ペーストしてから、ツリービュータブをクリックします。

IF TEST = 1
{
  ASSIGN Names = "Wes|Nate|Dan|Clay"
  ASSIGN EyeColors = "Blue|Blue|Brown|Brown"
  ASSIGN Signs = "Aquarius|Aries|Pisces|Leo"
  ASSIGN Foods = "Spagetti|Pizza|Sushi|Deep Fried Twinkies"
}

DYNAMIC Persons

ASSIGN PeopleCount = Names.size

FOR i = 1 TO PeopleCount
{
  ASSIGN Persons[i].Name = "{Names[i]}"
  ASSIGN Persons[i].Eyecolor = "{EyeColors[i]}"
  ASSIGN Persons[i].Sign = "{Signs[i]}"
  ASSIGN Persons[i].Food = "{Foods[i]}"
}

FOR i=1 TO 9
{
	a = "{a}{i}"
}
//Result: a="123456789"


FOR i=9 TO 1
{
	b = "{b}{i}"
}
//Result: b="987654321"

ForEach

説明：指定された文字列配列の各要素に対してループを1回繰り返します。

ツリービューのプロパティ

ツリービュータブでは、FOREACH がFOREACH i in arrayのように表示されます。

設定するプロパティは以下のとおりです：

ArrayName：スクリプトが定義された動作を適用する対象となる配列を含む変数名。
Comment：FOREACH ループに関するコメントを追加します。
Iterator：現在の配列要素を保持する変数の名前名を入力します。
Line Number：コマンドの行番号がエディターに表示されます。

FOREACHを完成させるには、FOREACH i in arrayを右クリックし、キーワードと動作を追加して、スクリプトで指定の配列内の各要素に対して実行する処理を定義します。

例

この例をツリービューで見るには、テキストビュータブにコピー＆ペーストしてから、ツリービュータブをクリックします。



IF TEST = 1 
{
	ASSIGN Names="Odin|Freya|Thor|Loki"
}
ASSIGN SubCounter=1
FOREACH Name IN Names
{
	IF Name = "Odin" |  Name = "Freya"
	{
		ASSIGN NewNames[SubCounter]= "{Name}"

		ASSIGN SubCounter=SubCounter + 1

	}
}

条件

説明：表現を評価し、評価の結果に応じてブランチを取ります。

Studioアクション：If (CXone Studio：Ifのヘルプページを参照)

ブーリアン演算子の詳細を知る

加減乗除の通常の数学演算子に加えて、以下の演算子を使用できます。

モジュロ演算子（%）
べき乗/指数（^）
整数除算（\)
排他的論理和（~）

すべての式に、通常の数学的演算順序が適用されます。括弧内のものはサブユニットとして最初に評価されます。指数/べき乗演算子は2番目に評価されます。そして次に乗算と除算、その後に加算と減算が評価されます。比較演算子は、すべての数学演算が終了した後、最後に評価されます。

ブーリアン演算

スニペットで次のブーリアン演算子を使用できます。これらの演算子はすべて、数値または文字列の比較で使用できます。文字列比較では、アルファベット順を使用して、大なり小なりを判定します。比較では、A＝1、Z＝26です。文字列比較では大文字と小文字が区別されます。

演算子記号	演算子名	詳細
=	等しい	式の両辺が等しい場合、式の結果は true (1)となり、そうでない場合は false (0)となります。
!=	等しくない	式の両辺が等しくない場合、式は true (1)と評価され、そうでない場合は0 false (0)となります。
>	より大きい	式の右辺が左辺より小さい場合、式の結果は true (1)となり、そうでない場合は false (0)となります。
>=	以上	式の右辺が左辺と等しいかそれより小さい場合、式の結果は true (1)となり、そうでない場合は false (0)となります。
<	未満	式の左辺が右辺より小さい場合、式の結果は true (1)となり、それ以外の場合は false (0)となります。
<=	以下	式の左辺が右辺と等しいかそれより小さい場合、式の結果は true (1)となり、そうでない場合は false (0)となります。
&	および	すべての部分式がtrueと評価される場合、式全体の結果は true (1)となり、そうでない場合は false (0)となります。
\|	または	いずれかの部分式がtrueと評価される場合、式の結果は true (1)となり、そうでない場合は false (0)となります。

ツリービューのプロパティ

ツリービュータブでは、IFが>IF 0のように表示され、その下に>TrueとFalseが続きます。>IFは、評価される表現を定義します。>Trueは、表現がtrueと評価された場合に何が起こるかを定義します。>Falseは、表現がfalseと評価された場合に何が起こるかを定義します。

設定するプロパティは以下のとおりです：

Comment：Ifステートメントに関するコメントを追加します。
Expression：スクリプトで評価する条件を入力します。
Line Number：エディターでのコマンドの行番号です。

IFステートメントを完成させるには、TrueとFalseを右クリックし、Expressionの評価に応じてスクリプトに実行させるキーワードや動作を選択します。TrueとFalseの両方にオプションを提供する必要はありません。キーワードや動作を複数追加することができます。必要に応じて、選択したキーワードや動作を設定します。

例

この例をツリービューで見るには、テキストビュータブにコピー＆ペーストしてから、ツリービュータブをクリックします。

IF TEST = 1
   {
      ASSIGN contactID = "123456780"
      ASSIGN customerName = "XYZ International"
      ASSIGN CBWindowStart = #"{date} 8:00 AM"
      ASSIGN CBWindowEnd = #"{date} 4:30 PM"
   }

//String Comparison

IF customerName = "ABC Corporation"
   {
      ASSIGN contractLevel = "Gold"
   }
   ELSE
      {
         ASSIGN contractLevel = "Silver"
      }

//Numeric Comparision

IF contactID % 10 = 0
   {
      ASSIGN logCall = 1
   }
   ELSE
      {
         ASSIGN logCall = 0
      }

//DateTime Comparison

ASSIGN myTime = #"{time}"

IF myTime >= CBWindowStart && myTime  <= CBWindowEnd
   {
      ASSIGN offerCallback = "True"
   }
   ELSE
      {
         ASSIGN offerCallback = "False"
      }

リピート

説明：指定されたコマンドを指定された回数実行します。

ツリービューのプロパティ

ツリービュータブでは、REPEATがREPEAT 0のように表示されます。

設定するプロパティは以下のとおりです：

Comment：繰り返しに関するコメントを追加します。
Line Number：コマンドの行番号がエディターに表示されます。
Repeat：数値として評価される式を入力して、指定した動作を繰り返す回数を定義します。

REPEATを完成させるには、REPEAT 0を右クリックし、スクリプトに繰り返させる動作を選択します。複数の動作を追加できます。選択した各動作を設定します。

例

この例をツリービューで見るには、テキストビュータブにコピー＆ペーストしてから、ツリービュータブをクリックします。


REPEAT 10
{
	phone = "{phone}{random(10)}"
}

戻る

説明：関数を終了し、オプションで関数からスクリプトに変数を渡します。FUNCTIONステートメントと一緒に使用します。

構文：RETURNまたはRETURN <var>

Studioアクション：Return (CXone Studio：Returnのヘルプページを参照)

詳細：関数宣言のコード内で使用しなければなりません。スクリプトに情報を戻すには、キーワードRETURNの後に変数名<var>を追加します。

選択

説明：trueと評価された最初の式に基づいて一連のコマンドを実行します。

ツリービューのプロパティ

ツリービュータブでは、SELECT がSELECT 0のように表示されます。

設定するプロパティは以下のとおりです：

Comment：SELECTに関するコメントを追加します。
Line Number：コマンドの行番号がエディターに表示されます。

SELECTを完成させるには、SELECT 0を右クリックし、スクリプトで評価する各式に対してCASE キーワードを追加します。DEFAULT 条件を追加して、定義されたCASE オプションのどれも適用されない場合のスクリプトの動作を指定します。各CASE とDEFAULT キーワードを設定します。

例

この例をツリービューで見るには、テキストビュータブにコピー＆ペーストしてから、ツリービュータブをクリックします。

SELECT
{
	CASE name="Odin" { agentid = 123 }
	CASE name="Frigg" { agentid = 345 }
	CASE name.length = 0
	 {
	   ASSIGN agentid = -1
	   ASSIGN error = "Invalid name"
	 }
	DEFAULT { ASSIGN agentid = 999 }
}

切り替え

説明：指定された変数を評価し、一致するCASEで定義されたアクションを実行します。

詳細： SWITCHは、変数の値を各CASEのリテラル値と比較します。一致するCASE が見つかると、SWITCHが実行され、一致するCASEに関連付けられた中括弧内のコード{ ... }に分岐します。

SWITCHが評価できるのは変数だけです。式を評価することはできません。式を使用した場合、スクリプトは機能しません。

少なくとも1つのCASEが必要です。すべての CASEステートメントは、同じ型のリテラルを持たなければなりません。最初のCASEが、残りのCASEステートメントのタイプを決定します。いずれかのCASEステートメントが最初のCASEと異なる型を持つ場合、コンパイラエラーが発生します。以下に、有効なリテラル型をすべて示します。

CASE "john"
CASE 512
CASE #"5/15/2050"
CASE #"6/1/2050 7:00am"
CASE #"7am"

例：

IF TEST = 1
{
  ASSIGN MyDate = "07/03/2023" //This date falls on a Monday
}
ASSIGN MyDow = MyDate.asdatedow
SWITCH MyDow
{
  CASE 0   { ASSIGN NewToday = "Sunday"  }
  CASE 1   { ASSIGN NewToday = "Monday"  }
  CASE 2   { ASSIGN NewToday = "Tuesday" }
  CASE 3   { ASSIGN NewToday = "Wednesday" }
  CASE 4   { ASSIGN NewToday = "Thursday" }
  CASE 5   { ASSIGN NewToday = "Friday"  }
  CASE 6   { ASSIGN NewToday = "Saturday"   }
}

ユースケース：SWITCHを使用すると、指定された変数が何を含むかによって、特定の結果を得ることが可能です。例えば、スクリプトで市外局番を含む変数を評価させるとします。可能性のある市外局番ごとにCASEを定義し、その市外局番が割り当てられている州に一致する値を、変数stateに追加することができます。例：

SWITCH areaCode
{
	CASE 603 { state =  "New Hampshire" }
	CASE 614 { state =  "Ohio" }
	CASE 628 { state =  "California" }
	CASE 646 { state =  "New York" }
	CASE 667 { state =  "Maryland" }
}

この例をツリービューで見るには、テキストビュータブにコピー＆ペーストしてから、ツリービュータブをクリックします。

ツリービューのプロパティ

ツリービュータブでは、SWITCH がSWITCH 0のように表示されます。

設定するプロパティは以下のとおりです：

Comment：SWITCHに関するコメントを追加します。
Expression：
Line Number：コマンドの行番号がエディターに表示されます。

SWITCHを完成させるには、SWITCH 0を右クリックし、スクリプトで評価する各条件に対してCASE キーワードを追加します。DEFAULT 条件を追加して、定義されたCASE オプションのどれも適用されない場合のスクリプトの動作を指定します。各CASE とDEFAULT キーワードを設定します。

トレース

説明：テキストビュータブでデバッガーを使用する際、テキストをSnippet editorウィンドウの結果パネルに出力します。

構文：TRACE "<value>"

詳細：デバッガーを使用する際にSnippet editorウィンドウの結果パネルに表示させる任意の"<value>"に、TRACEキーワードを追加します。<value>は変数名にすることができます。TRACEは、コードの問題をトラブルシューティングするときや、スクリプトで何が起こっているかを確認するときに役立つツールです。

このキーワードは、Snippetアクションでのみ使用されます。TRACEキーワードはスニペットに残しておいても安全です。実行時、Snippet editorウィンドウのデバッガーツールの外では無視されます。

ツリービューのプロパティ

ツリービュータブで、TRACE で設定するプロパティは次のとおりです。

AllowEscapes：trueに設定すると、バックスラッシュ文字（\）で始まるエスケープシーケンスを埋め込むことができます。デフォルトはfalseです。
Comment：トレースに関するコメントを追加します。
Expression：結果ペインに出力するテキスト。変数を中括弧で囲んで含めることができます{ }。例えば、 {agentId} 。
Line Number：エディターでのコマンドの行番号です。

例

この例をツリービューで見るには、テキストビュータブにコピー＆ペーストしてから、ツリービュータブをクリックします。

TRACE "this is trace text"
//The text you specify with TRACE appears 
//In the results window when you use the 
//Debugger on the Text View tab.

説明：スニペット内で使用するSOAP WebサービスのプロキシDLLを含めることができます。DLLはNICE CXoneによるWISDLでコンパイルする必要があります。

構文：USES "<proxy>.dll"

Studioアクション：Uses(CXone Studio：Usesのヘルプページを参照)

詳細： USESステートメントを使用するには、プロキシDLLがテナントのテクニカルサポート、請求、およびCXone環境のグローバル設定の管理に使用される高レベルの組織グループファイルサーバーのルートフォルダーになければなりません。CXoneのACDファイルを閲覧するページで、テナント内のファイルを確認することができます。

詳細：SNIPPETアクションからのAPI呼び出しについてのヘルプページで、StudioスクリプトでのWebサービスプロキシの使用について詳しく説明しています。

ツリービューのプロパティ

ツリービュータブでは、用途がUSES ""のように表示されます。

設定するプロパティは以下のとおりです：

Comment：キーワードに関するコメントを追加します。
FileName：スニペット内で使用するプロキシDLLファイルの名前を追加します。
Line Number：コマンドの行番号がエディターに表示されます。

それぞれのキーワードにCommentプロパティがあります。これにより、そのキーワードに関するコメントを追加することができます。Commentオプションを使用して、特定のプロパティに関連しないコメントを追加します。